FlashVars and AS2

6 Jun, 2006  AS2

When using FlashVars variables are pushed directly from the HTML-embedding of the Flash instance into the main timeline – _level0 that is.

To avoid having _level0.some_flashvar spread around the code without knowing, whether they exist, where they are used and more, I normally use a dynamic singleton FlashVars-class for first parsing these in the main timeline, and subsequently using this singleton class when loading vars.

The class is defined as:

Actionscript:
  1. dynamic class org.barklund.utils.FlashVars {
  2.     /* vars */
  3.     private static var instance:FlashVars;
  4.     private var vars:Object;
  5.     /* can be overriden or cleared by inheritance */
  6.     private var prefix:String = "fv_";
  7.     /* constructor */
  8.     private function FlashVars() {
  9.         // init hashmap
  10.         vars = new Object();
  11.         // set __resolve to use getVar-function for dynamic references
  12.         __resolve = getVar;
  13.     }
  14.     /* singleton */
  15.     public static function getInstance():FlashVars {
  16.         return instance ? instance : instance = new FlashVars();
  17.     }
  18.     /* parse through movieclip */
  19.     public function parse(p:MovieClip):Void {
  20.         for (var i:String in p) {
  21.             if (prefix) {
  22.                 if (i.indexOf(prefix) !== 0) {
  23.                     continue;
  24.                 }
  25.                 setVar(i.substring(prefix.length), p[i]);
  26.             } else {
  27.                 setVar(i, p[i]);
  28.             }
  29.         }
  30.     }
  31.     /* get and set */
  32.     private function setVar(n:String, v:String):Void {
  33.         vars[n] = v;
  34.     }
  35.     public function getVar(n:String):String {
  36.         return vars[n] !== undefined ? String(vars[n]) : null;
  37.     }
  38. }

And it can be used as for instance on the main timeline:

Actionscript:
  1. import org.barklund.utils.FlashVars;
  2. FlashVars.getInstance().parse(this);

And variables can be read like:

Actionscript:
  1. import org.barklund.utils.FlashVars;
  2. class org.barklund.someproject.SomeClass {
  3.     ...
  4.     var fv:FlashVars = FlashVars.getInstance();
  5.     var id:Number = parseInt(fv.id);
  6.     var name:String = String(fv.name);
  7. }

It can also be extended with a non-dynamic class for strong typing (though it requires extending singleton-ness, which is quite strange-looking):

Actionscript:
  1. import org.barklund.utils.FlashVars;
  2. class org.barklund.someproject.SomeSettingsClass extends FlashVars {
  3.     /* override singleton */
  4.     public static function getInstance():SomeSettingsClass {
  5.         return SomeSettingsClass(instance ? instance : instance = new SomeSettingsClass());
  6.     }
  7.     /* public accessors */
  8.     public function get id():Number {
  9.         return Number(getVar("id"));
  10.     }
  11.     public function get name():Number {
  12.         return Number(getVar("name"));
  13.     }
  14. }

This class is not dynamic in order to make the user of this only use these two variables. Other variables from the FlashVars-object can be read via getVar though (inherited publicly), so this could also be redeclared as private.

4 Comments so far »

  1. janosch said

    at June 6 2006 @ 13:03

    Thx, nice idea!

    You could overwrite the instance-variable too:

    private static var instance:SomeSettingsClass;
    public static function getInstance():SomeSettingsClass {
    return instance ? instance : instance = new SomeSettingsClass();
    }

    So you can omit the SomeSettingsClass-cast.

  2. Barklund said

    at June 6 2006 @ 13:10

    Yes, that would be possible, but I’m not sure if it makes it better. At least that would separate the two singletons completely thus creating nicer code, but I’m not sure whether a separation is desirable.

  3. Neh said

    at June 7 2006 @ 05:30

    really good example…

  4. Abe Pazos said

    at January 3 2007 @ 13:06

    Hi! Thanks for sharing!

    What would be your approach to simulate FlashVars using this class when outside HTML? (inside FlashDevelop for example)

    Thank you + happy 007 :)

    aBe

Comment RSS · TrackBack URI

Leave a comment

Name: (Required)

eMail: (Required)

Website:

Comment: